ここから本文です

レジストリについて質問です。 reg Deleteでサブキーを削除したいのですが、う...

ua0********さん

2018/2/714:49:53

レジストリについて質問です。

reg Deleteでサブキーを削除したいのですが、うまくできません。
また、エラーが表示されてしまいます。
エラー:指定されたレジストリの値が見つかりません

HKLM¥software¥Wow6432Node¥MOTEX¥LanScope Cat MR¥InvInfo
の下にあるサブキーを削除する方法をご教授いただけないでしょうか。

また、サブキーはたくさんあり1回で全てのサブキーを削除する方法もありましたら、併せてご教授いただければと思います。

よろしくお願いいたします。

補足削除できました!
ですが、サブキーを1つずつ削除しなくてはいけないのか、もしくは一括で削除できる方法がございましたら、ご教授いただけないでしょうか。

閲覧数:
448
回答数:
1

違反報告

ベストアンサーに選ばれた回答

あるキーの下のサブキーを削除するには、そのサブキー、1個づつ削除するしかないと思います。

あるキー(ここでは、InvInfo)にデータがあるなら、それを保存した後、InvInfoのキーごと削除して、InvInfoのキーをまた作って、保存したデータをリストアするとか・・・・・。

後は、「InvInfo」キーのサブキーを1個づつ削除するバッチファイルを作る・・・とかでしょうか・・・。

一応、バッチファイルを作ってみました。以下をメモ帳にコピペして、拡張子を bat にして保存してダブルクリックで実行。

ただ、レジストリを手動で編集や削除する場合は、一般的には、起動不能になる場合があるので気をつけなければなりません。

こんなに、削除して大丈夫なのでしょうか・・・?




@echo off
openfiles >nul 2>&1 && goto START
powershell.exe -Command Start-Process "%~f0%" -Verb Runas
exit

:START
setlocal enabledelayedexpansion
set reg_path=HKEY_LOCAL_MACHINE\SOFTWARE\WOW6432Node\MOTEX\LanScope Cat MR\InvInfo
set cnt=0
set flag=0

:MAIN
for /F "delims=" %%i in ('reg query "%reg_path%"') do (
set reg1=%%i
call :SUB
)

if %cnt% EQU 0 (
echo 削除するサブキーがありません。
goto END
)
if %flag% EQU 0 (
echo.
echo %reg_path% の上記のサブキー %cnt%個を削除します。
choice /n /m "実行する場合は yキーを、キャンセルする場合は nキーを押してください。"
if !errorlevel! EQU 1 (
set flag=1
goto MAIN
)
)

:END
echo.
echo 何かキーを押すと、この画面を閉じます。
pause>nul
exit

:SUB
echo %reg1% | find /i "%reg_path%">nul 2>&1
if %errorlevel% NEQ 0 goto :EOF
if /i "%reg1%"=="%reg_path%" goto :EOF
set /a cnt+=1
call set reg2=%%reg1:%reg_path%\=%%
if %flag% EQU 0 (
echo. %reg2%
) else (
if /i "%reg1%"=="%reg_path%" goto :EOF
echo [%reg2%]キーを削除
reg delete "%reg1%" /f
)
goto :EOF

質問した人からのコメント

2018/2/9 12:30:30

バッチまで作成していただいてありがとうございます。
今現在は、1つ1つ削除する方法で削除対応しています。
私はバッチの作成方法がわからなかったので、記載いただいたバッチの動きがわからないのですが、個別で教えていただけるととても嬉しいです。

今回はご回答いただきありがとうございました。

あわせて知りたい

みんなで作る知恵袋 悩みや疑問、なんでも気軽にきいちゃおう!

Q&Aをキーワードで検索:

Yahoo! JAPANは、回答に記載された内容の信ぴょう性、正確性を保証しておりません。
お客様自身の責任と判断で、ご利用ください。
本文はここまでです このページの先頭へ

「追加する」ボタンを押してください。

閉じる

※知恵コレクションに追加された質問は選択されたID/ニックネームのMy知恵袋で確認できます。

不適切な投稿でないことを報告しました。

閉じる