VBSを使ってCSVファイルを操作したいです。 以下のように日付データのみが格納...

再度追加仕様があったので、再度回答し直してます

> さらにそれ以外の日を判断したいです。
> その他用のファイルを作り形式は同じで、
> 2020/01/01のような日付が記載されている場合、
> 005に変えるようなこともできますでしょうか。

祝日用ファイル：csv3.csv
他用途ファイル：csv4.csv
として、必ず存在することを前提に（各ファイルパスは変更ください）


Dim dic4, dic5, sFile1, sFile2, sA(2), sBuf, ffn2, vC, v
Const CFILE2 = "csv2.csv"
Const ForReading = 1, ForWriting = 2

Set dic4 = CreateObject("Scripting.Dictionary")
Set dic5 = CreateObject("Scripting.Dictionary")
sFile1 = "D:\HogeMoge\csv1.csv" ' ★
vC = Array( _
      Array("D:\HogeMoge\csv3.csv", "004", dic4), _
      Array("D:\HogeMoge\csv4.csv", "005", dic5) _
   )

sFile2 = Left(sFile1, InStrRev(sFile1, "\")) & CFILE2
sA(0) = "コード": sA(1) = "日付": sA(2) = "日付コード"

With CreateObject("Scripting.FileSystemObject")
   For Each v In vC
      With .OpenTextFile(v(0), ForReading)
         While (Not .AtEndOfStream)
            sBuf = .ReadLine
            If (IsDate(sBuf)) Then v(2)(CDate(sBuf)) = v(1)
         Wend
         .Close
      End With
   Next

   Set ffn2 = .OpenTextFile(sFile2, ForWriting, True)
   ffn2.WriteLine Join(sA, ",")
   sA(0) = "1000"
   With .OpenTextFile(sFile1, ForReading)
      While (Not .AtEndOfStream)
         sBuf = .ReadLine
         If (IsDate(sBuf)) Then
            sA(1) = sBuf
            Select Case Weekday(sBuf)
               Case vbSunday: sA(2) = "001"
               Case vbSaturday: sA(2) = "002"
               Case Else
                  sA(2) = "003"
                  sBuf = CDate(sBuf)
                  For Each v In Array(dic4, dic5)
                     If (v.Exists(sBuf)) Then
                        sA(2) = v(sBuf)
                        Exit For
                     End If
                  Next
            End Select
            ffn2.WriteLine Join(sA, ",")
         End If
      Wend
      .Close
   End With
   ffn2.Close
   Set ffn2 = Nothing
End With
Set dic4 = Nothing
Set dic5 = Nothing
MsgBox "完了"



以下、再回答 2019/11/18 15:18:15

追加仕様があったので、回答し直してます

> 今は土日とそれ以外で出していますが、
> たとえば別csvファイルに祝日を記載しておいて、それ以外で出した
> 「003」を「004」に変えるようなことはできますでしょうか。

> csv1.csv と同じ形式で祝日をyyyy/mm/ddで記載します。
> ----csv3----
> 2019/10/22
> 2019/11/04

> 11/3は001、11/4は004になります。
> 祝日ファイルには2019/11/04とだけ記載
> （11/3は祝日ですが日曜日なので記載しない）

変更した点は

祝日用ファイルフルパスを指定しておく（sFile3 として）※変更要
祝日を Dictionay のキーとして覚え込む
csv1.csv と 祝日ファイル内の各書式が異なっても動くように、
文字列→日付型に変更したもので覚えておく
そして、土日でなかった場合、Dictionary に覚えていたら 004 に


※ 提示している記述は、先ず、Excel の標準モジュールに記述して･･･
簡単な動作確認後、vbs ファイルとして転記して････
（vbs でのデバッグは面倒なので）
なので、文字列の各スペル内の大文字・小文字は VBE が勝手に･･･
メモ帳に直に記述すると、全部小文字にしちゃうかも･･･

どうなりますか


Dim dic, sFile1, sFile2, sFile3, sA(2), sBuf, ffn2
Const CFILE2 = "csv2.csv"
Const ForReading = 1, ForWriting = 2

Set dic = CreateObject("Scripting.Dictionary")
sFile1 = "D:\HogeMoge\csv1.csv" ' ★
sFile3 = "D:\HogeMoge\csv3.csv" ' ★ 祝日用ファイル

sFile2 = Left(sFile1, InStrRev(sFile1, "\")) & CFILE2
sA(0) = "コード": sA(1) = "日付": sA(2) = "日付コード"

With CreateObject("Scripting.FileSystemObject")
   With .OpenTextFile(sFile3, ForReading)
      While (Not .AtEndOfStream)
         sBuf = .ReadLine
         If (IsDate(sBuf)) Then dic(CDate(sBuf)) = Empty
      Wend
      .Close
   End With

   Set ffn2 = .OpenTextFile(sFile2, ForWriting, True)
   ffn2.WriteLine Join(sA, ",")
   sA(0) = "1000"
   With .OpenTextFile(sFile1, ForReading)
      While (Not .AtEndOfStream)
         sBuf = .ReadLine
         If (IsDate(sBuf)) Then
            sA(1) = sBuf
            Select Case Weekday(sBuf)
               Case vbSunday: sA(2) = "001"
               Case vbSaturday: sA(2) = "002"
               Case Else
                  sA(2) = "003"
                  If (dic.Exists(CDate(sBuf))) Then sA(2) = "004"
            End Select
            ffn2.WriteLine Join(sA, ",")
         End If
      Wend
      .Close
   End With
   ffn2.Close
   Set ffn2 = Nothing
End With
Set dic = Nothing
MsgBox "完了"




以下、初期回答 2019/11/14 17:02:55


以下でどうなりますか

★ 部分のファイルフルパスを書き換えて････
csv2.csv は、同じフォルダに


Dim sFile1, sFile2, sA(2), sBuf, ffn2
Const CFILE2 = "csv2.csv"
Const ForReading = 1, ForWriting = 2

sFile1 = "D:\HogeMoge\csv1.csv" ' ★

sFile2 = Left(sFile1, InStrRev(sFile1, "\")) & CFILE2
sA(0) = "コード": sA(1) = "日付": sA(2) = "日付コード"

With CreateObject("Scripting.FileSystemObject")
   Set ffn2 = .OpenTextFile(sFile2, ForWriting, True)
   ffn2.WriteLine Join(sA, ",")
   sA(0) = "1000"
   With .OpenTextFile(sFile1, ForReading)
      While (Not .AtEndOfStream)
         sBuf = .ReadLine
         If (IsDate(sBuf)) Then
            sA(1) = sBuf
            Select Case Weekday(sBuf)
               Case vbSunday: sA(2) = "001"
               Case vbSaturday: sA(2) = "002"
               Case Else: sA(2) = "003"
            End Select
            ffn2.WriteLine Join(sA, ",")
         End If
      Wend
      .Close
   End With
   ffn2.Close
   Set ffn2 = Nothing
End With
MsgBox "完了"